【已解决】 我想要一個原檔..

TWYorick

invis.sma
就是可以隱藏水面的那一類
不然我玩單機會掉fps

dsm635625

1. 
   
2. #include <amxmodx>
   
3. #include <fakemeta>
   
4. #include <hamsandwich>
   
5. 
   
6. #pragma semicolon 1
   
7. 
   
8. new bool:g_bPlayerInvisible[33], bool:g_bWaterInvisible[33];
   
9. new bool:g_bWaterEntity[1385], bool:g_bWaterFound;
   
10. 
    
11. new g_iSpectatedId[33];
    
12. 
    
13. public plugin_init( )
    
14. {
    
15.         register_plugin( "Invis", "1.2b", "SchlumPF");
    
16.        
    
17.         register_clcmd( "say /invis", "menuInvisDisplay" );
    
18.         register_menucmd( register_menuid( "\rInvisibility - SchlumPF^n^n" ), 1023, "menuInvisAction" );
    
19.        
    
20.         register_forward( FM_PlayerPreThink, "fwdPlayerPreThink_Pre", 0 );
    
21.         register_forward( FM_AddToFullPack, "fwdAddToFullPack_Pre", 0 );
    
22.        
    
23.         RegisterHam( Ham_Spawn, "player", "hamSpawnPlayer_Post", 1 );
    
24. }
    
25. 
    
26. public plugin_cfg( )
    
27. {
    
28.         // find all water entitys to make AddToFullPack use less cpu
    
29.         new ent = engfunc( EngFunc_FindEntityByString, -1, "classname", "func_water" );
    
30.         while( ent > 0 )
    
31.         {
    
32.                 if( !g_bWaterFound )
    
33.                         g_bWaterFound = true;
    
34. 
    
35.                 g_bWaterEntity[ent] = true;
    
36.                
    
37.                 ent = engfunc( EngFunc_FindEntityByString, ent, "classname", "func_water" );
    
38.         }
    
39. }
    
40. 
    
41. public fwdPlayerPreThink_Pre( plr )
    
42. {
    
43.         if( !is_user_alive( plr ) )
    
44.         {
    
45.                 g_iSpectatedId[plr] = pev( plr, pev_iuser2 );
    
46.         }
    
47. }
    
48. 
    
49. public fwdAddToFullPack_Pre( es_handle, e, ent, host, hostflags, player, pset )
    
50. {
    
51.         if( player )
    
52.         {
    
53.                 if( g_bPlayerInvisible[host] && host != ent )
    
54.                 {
    
55.                         if( ent != g_iSpectatedId[host] )
    
56.                         {
    
57.                                 return FMRES_SUPERCEDE;
    
58.                         }
    
59.                 }
    
60.         }
    
61.         else if( g_bWaterInvisible[host] )
    
62.         {
    
63.                 if( g_bWaterEntity[ent] )
    
64.                 {
    
65.                         return FMRES_SUPERCEDE;
    
66.                 }
    
67.         }
    
68.        
    
69.         return FMRES_IGNORED;
    
70. }
    
71. 
    
72. public hamSpawnPlayer_Post( plr )
    
73.         g_iSpectatedId[plr] = 0;
    
74. 
    
75. public menuInvisDisplay( plr )
    
76. {
    
77.         static menu[2048];
    
78.         new keys = ( 1<<0 | 1<<1 | 1<<9 );
    
79.        
    
80.         static player[3];
    
81.         format( player, sizeof player - 1, "%s", g_bPlayerInvisible[plr] ? "\d" : "\w" );
    
82.        
    
83.         new len = format( menu, sizeof menu - 1, "\rInvisibility - SchlumPF^n^n" );
    
84.        
    
85.         len += format( menu[len], sizeof menu - len, "\r01. %sPlayers^n", player );
    
86. 
    
87.         if( g_bWaterFound )
    
88.         {
    
89.                 static water[3];
    
90.                 format( water, sizeof water - 1, "%s", g_bWaterInvisible[plr] ? "\d" : "\w" );
    
91. 
    
92.                 len += format( menu[len], sizeof menu - len, "\r02. %sWater^n^n", water );
    
93.         }
    
94.         else
    
95.                 len += format( menu[len], sizeof menu - len, "\d02. Water^n^n" );
    
96. 
    
97.         len += format( menu[len], sizeof menu - len, "\r00. \wExit" );
    
98.        
    
99.         show_menu( plr, keys, menu, -1 );
    
100.                
     
101.         return PLUGIN_HANDLED;
     
102. }
     
103. 
     
104. public menuInvisAction( plr, key )
     
105. {
     
106.         switch( key )
     
107.         {
     
108.                 case 0:
     
109.                 {
     
110.                         if( g_bPlayerInvisible[plr] )
     
111.                         {
     
112.                                 g_bPlayerInvisible[plr] = false;
     
113.                                 fnGreenChat( plr, "[XJ] All players are now visible." );
     
114.                         }
     
115.                         else
     
116.                         {
     
117.                                 g_bPlayerInvisible[plr] = true;
     
118.                                 fnGreenChat( plr, "[XJ] All players are now invisible." );
     
119.                         }
     
120.                        
     
121.                         menuInvisDisplay( plr );
     
122.                 }
     
123.                 case 1:
     
124.                 {
     
125.                         if( g_bWaterFound )
     
126.                         {
     
127.                                 if( g_bWaterInvisible[plr] )
     
128.                                 {
     
129.                                         g_bWaterInvisible[plr] = false;
     
130.                                         fnGreenChat( plr, "[XJ] Water is now visible." );
     
131.                                 }
     
132.                                 else
     
133.                                 {
     
134.                                         g_bWaterInvisible[plr] = true;
     
135.                                         fnGreenChat( plr, "[XJ] Water is now invisible." );
     
136.                                 }
     
137.                         }
     
138.                         else
     
139.                                 fnGreenChat( plr, "[XJ] There is no water which can become invisible." );
     
140.        
     
141.                         menuInvisDisplay( plr );
     
142.                 }
     
143.                 case 9: show_menu( plr, 0, "" );
     
144.         }
     
145.        
     
146.         return PLUGIN_HANDLED;
     
147. }
     
148. 
     
149. public client_connect( plr )
     
150. {
     
151.         g_bPlayerInvisible[plr] = false;
     
152.         g_bWaterInvisible[plr] = false;
     
153.         g_iSpectatedId[plr] = 0;
     
154. }
     
155. 
     
156. 
     
157. // by fatalis
     
158. fnGreenChat( plr, const message[], {Float,Sql,Result,_}:... )
     
159. {
     
160.         static max_players, svc_saytext;
     
161.         if( !max_players )
     
162.                 max_players = get_maxplayers( );
     
163.         if( !svc_saytext )
     
164.                 svc_saytext = get_user_msgid( "SayText" );
     
165.        
     
166.         static msg[192];
     
167.         msg[0] = 0x04;
     
168.        
     
169.         vformat( msg[1], sizeof msg - 2, message, 3 );
     
170.        
     
171.         if( plr > 0 && plr <= max_players )
     
172.         {
     
173.                 message_begin( MSG_ONE, svc_saytext, { 0, 0, 0 }, plr );
     
174.                 write_byte( plr );
     
175.                 write_string( msg );
     
176.                 message_end( );
     
177.         }
     
178.         else if( plr == 0 )
     
179.         {
     
180.                 for( new i = 1 ; i <= max_players ; i++ )
     
181.                 {
     
182.                         if( is_user_connected( i ) )
     
183.                         {
     
184.                                 message_begin( MSG_ONE, svc_saytext, { 0, 0, 0 }, i );
     
185.                                 write_byte( i );
     
186.                                 write_string( msg );
     
187.                                 message_end( );
     
188.                         }
     
189.                 }
     
190.         }
     
191.        
     
192.         return 1;
     
193. }
     
194. 
     

复制代码

Jackey.lia

:dizzy::dizzy::dizzy::dizzy::dizzy::dizzy::dizzy:

TWYorick

感謝 可以用的.. THX

MaMaMiYa

本人已经放弃写插件

Ns.

很迷糊的说

wangkai101

看见插件就迷糊